Nápověda LibreOffice 24.8
Tato kategorie obsahuje informační funkce.
Údaje v následující tabulce slouží jako základ pro některé příklady v popisu funkcí.
| C | D | |
|---|---|---|
| 2 | hodnota x | hodnota y | 
| 3 | -5 | -3 | 
| 4 | -2 | 0 | 
| 5 | -1 | 1 | 
| 6 | 0 | 3 | 
| 7 | 2 | 4 | 
| 8 | 4 | 6 | 
| 9 | 6 | 8 | 
Vrátí informaci o adrese, formátování nebo obsahu buňky.
CELL("Informace" [; Odkaz])
InfoType je řetězec znaků , který specifikuje typ informací.Řetězec znaků je vždy v angličtině. Velká nebo malá písmena jsou volitelná.
| InfoType | Význam | 
|---|---|
| COL | Vrátí číslo odkazovaného sloupce. =CELL("COL";D2) vrací 4. | 
| ROW | Vrátí číslo odkazovaného řádku. =CELL("ROW";D2) vrací 2. | 
| SHEET | Vrátí číslo odkazovaného listu. =CELL("Sheet";Sheet3.D2) vrací 3. | 
| ADDRESS | Vrátí absolutní adresu odkazované buňky. =CELL("ADDRESS";D2) vrací $D$2. =CELL("ADDRESS";Sheet3.D2) vrací $Sheet3.$D$2. =CELL("ADDRESS";'X:\dr\test.ods'#$Sheet1.D2) vrací 'file:///X:/dr/test.ods'#$Sheet1.$D$2. | 
| FILENAME | Vrátí název souboru a číslo listu odkazované buňky. =CELL("FILENAME";D2) vrací 'file:///X:/dr/own.ods'#$Sheet1, pokud je vzorec ve zvoleném dokumentu X:\dr\own.ods umístěný v sešitu Sheet1. =CELL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) vrací 'file:///X:/dr/test.ods'#$Sheet1. | 
| COORD | Vrátí úplnou adresu buňky ve formátu zápisu aplikace Lotus(TM). =CELL("COORD"; D2) vrátí $A:$D$2. =CELL("COORD"; Sheet3.D2) vrátí $C:$D$2. | 
| CONTENTS | Vrátí obsah odkazované buňky bez jakéhokoliv formátování. | 
| TYPE | Vrátí typ obsahu buňky: b = prázdná buňka, l = text, výsledek vzorce v podobě textu, v = hodnota, výsledek vzorce v podobě čísla. | 
| WIDTH | Vrátí šířku odkazovaného sloupce. Vrácené číslo udává počet číslic 0, které mohou být zadány do sloupce ve výchozí velikosti výchozího typu písma. | 
| PREFIX | Vrátí podobu zarovnání odkazované buňky: ' = označuje zarovnání vlevo, " = označuje zarovnání vpravo, ^ = označuje zarovnání na střed, \ = opakuji (nyní neaktivní) | 
| PROTECT | Vrátí informaci o stavu zamknutí buňky: 1 = buňka je zamknuta, 0 = buňka není zamknuta. | 
| FORMAT | Vrátí řetězec znaků označujících formát čísla: , = číslo obsahuje oddělovač v řádu tisíců, F = číslo neobsahuje oddělovač v řádu tisíců, C = formát měny, S = exponenciální reprezentace, např. 1,234+E56 P = procenta Ve formátech výše je počet desetinných míst za oddělovačem desetinných míst zadán jako číslo. Například formát čísla #,##0.0 vrátí ,1 a formát čísla 00.000% vrátí P3 D1 = D. MMM YYYY a podobné formáty, D2 = DD-MM D3 = MM. YY D4 = DD. MM. YY HH:MM, D5 = MM-DD, D6 = HH:MM:SS AM/PM, D7 = HH:MM AM/PM, D8 = HH:MM:SS, D9 = HH:MM, G = ostatní formáty, - (minus) na konci = záporná čísla jsou zobrazována barevně, () (závorky) na konci = kód formátu obsahuje levou závorku. | 
| COLOR | Vrátí číslo 1, jsou-li záporné hodnoty zobrazovány barevně. Jinak vrátí číslo 0. | 
| PARENTHESES | Vrátí číslo 1, pokud kód formátu obsahuje levou závorku (, jinak vrátí číslo 0. | 
Odkaz (seznam voleb) je pozice buňky k otestování. Je-li Odkaz oblast buněk, buňka se přesune na horní levou buňku oblast. Pokud Odkaz chybí, LibreOffice Calc použije pozici buňky, kde je umístěn tento vzorec. Microsoft Excel používá odkaz na buňku, kde je umístěn kurzor.
Tato funkce vrátí aktuální výsledek vyhodnocení vzorce, kterého je součástí (jinými slovy výsledek, pokud ho vyhodnocení má). Používá se zejména s funkcí STYLE() pro použití vybraných stylů na buňku podle jejího obsahu.
CURRENT()
=1+2+CURRENT()
Příklad vrátí 6. Vzorec se vypočítá zleva doprava takto: 1+2 rovná se 3 a tento výsledek je předán funkci CURRENT(). CURRENT() proto tento výsledek 3 přidá k původnímu číslu 3 a vrátí se 6.
=A2+B2+STYLE(IF(CURRENT()>10;"Chyba";"Dobré"))
Příklad vrátí A2+B2 (STYLE zde vrací 0). Pokud je součet větší než 10, pro buňku se použije styl „Chyba“. Další vysvětlení naleznete u funkce STYLE.
="choo"&CURRENT()
Příklad vrátí choochoo.
ORG.OPENOFFICE.CURRENT
Zobrazí vzorec buňky jako textový řetězec.
FORMULA(Odkaz)
Odkaz je odkazem na buňku obsahující vzorce.
Neplatný odkaz nebo odkaz na buňku neobsahující vzorec vrací chybovou hodnotu #N/A.
Pokud buňka A8 obsahuje vzorec =SUM(1;2;3), potom
=FORMULA(A8) vrací text =SUM(1;2;3).
Vrátí hodnotu, pokud buňka neobsahuje chybovou hodnotu, v opačném případě vrátí alternativní hodnotu.
IFERROR(Hodnota; Alternativní hodnota)
Hodnota je hodnota nebo výraz, který se má vrátit, pokud se nerovná chybě nebo neskončí chybou.
Alternativní hodnota je hodnota nebo výraz, který se má vrátit, pokud se výraz nebo hodnota Hodnota rovná chybě nebo skončí chybou.
=IFERROR(C8;C9), kde buňka C8 obsahuje =1/0 vrátí hodnotu C9, protože 1/0 je chybou.
=IFERROR(C8;C9), kde buňka C8 obsahuje 13, vrátí 13, hodnotu C8, která není chybou.
Vrátí hodnotu, pokud buňka neobsahuje chybovou hodnotu #N/A (hodnota není k dispozici), v opačném případě vrátí alternativní hodnotu.
IFNA(Hodnota; Alternativní hodnota)
Hodnota je hodnota nebo výraz, který se má vrátit, pokud se nerovná chybě #N/A nebo jí neskončí.
Alternativní hodnota je hodnota nebo výraz, který se má vrátit, pokud se hodnota nebo výraz Hodnota rovná chybě #N/A nebo jí skončí.
=IFNA(D3;D4) vrátí hodnotu buňky D3, pokud D3 neskončí chybou #N/A, nebo buňky D4, pokud jí skončí.
Vrací informace o aktuálním pracovním prostředí. Funkce přijme jeden textový argument a vrátí data v závislosti na tomto parametru.
INFO("Typ")
Následující tabulka zobrazuje hodnoty textového parametru "Typ" a návratové hodnoty funkce INFO.
| Hodnota pro "Typ" | Návratová hodnota | 
|---|---|
| "osversion" | Z důvodu kompatibility vždy "Windows (32-bit) NT 5.01" | 
| "system" | Typ operačního systému: | 
| "release" | Identifikace vydání produktu, např. "300m25(Build:9876)" | 
| "numfile" | Z důvodů kompatibility vždy 1 | 
| "recalc" | Aktuální režim přepočtu vzorců, buď "Automatic" nebo "Manual" (lokalizováno do jazyka LibreOffice) | 
Jiný tabulkový procesor může připouštět lokalizované hodnoty pro parametr Typ, ale LibreOffice Calc připouští pouze anglické hodnoty.
=INFO("vydání") vrací číslo vydání produktu používané aplikace LibreOffice.
=INFO(D5), kde buňka D5 obsahuje textový řetězec system, vrací typ systémové operace.
Vrátí PRAVDA, je-li odkazovaná buňka prázdná. Tato funkce se používá pro zjištění, je-li obsah buňky prázdný. Buňka se vzorcem není prázdná.
ISBLANK(Hodnota)
Hodnota je obsah pro testování.
=ISBLANK(D2) vrátí jako výsledek NEPRAVDA.
Zkontroluje, zda nastane chyba (s výjimkou #N/A), a vrátí PRAVDA nebo NEPRAVDA.
ISERR(Hodnota)
Hodnota je jakákoli hodnota nebo výraz, kde má být proveden test, zda je to chybová hodnota (kromě #N/A).
=ISERR(C8), kde buňka C8 obsahuje =1/0, vrátí PRAVDA, protože 1/0 je chyba.
=ISERR(C9), kde buňka C9 obsahuje =NA(), vrátí NEPRAVDA, protože ISERR() ignoruje chybu #N/A .
Zkontroluje, zda nastane chyba (včetně #N/A), a vrátí PRAVDA nebo NEPRAVDA.
ISERROR(Hodnota)
Hodnota je jakákoli hodnota nebo výraz, kde má být proveden test. ISERROR() vrátí PRAVDA, pokud nastane chyba, jinak vrátí NEPRAVDA.
=ISERROR(C8), kde buňka obsahuje =1/0, vrátí PRAVDA, protože 1/0 je chyba.
=ISERROR(C9), kde buňka C9 obsahuje =NA(), vrátí PRAVDA.
Vrátí PRAVDA, jestliže hodnota je celé sudé číslo, nebo NEPRAVDA, jestliže je celé liché.
ISEVEN(hodnota)
Hodnota je hodnota, která bude testována.
Není-li hodnota celé číslo, číslice za desetinnou čárkou budou ignorovány. Znaménko hodnoty bude také ignorováno.
=ISEVEN(48) vrátí PRAVDA
=ISEVEN(33) vrátí NEPRAVDA
=ISEVEN(0) vrátí PRAVDA
=ISEVEN(-2.1) vrátí PRAVDA
=ISEVEN(3.999) vrátí NEPRAVDA
Testuje sudá čísla. Vrátí 1, je-li číslo beze zbytku dělitelné dvěma.
ISEVEN_ADD(Číslo)
Číslo je číslo, které bude testováno.
=ISEVEN_ADD(5) vrátí 0.
=ISEVEN_ADD(A1) vrátí 1, pokud buňka A1 obsahuje číslo 2.
Vrátí PRAVDA, pokud buňka obsahuje vzorec.
ISFORMULA(Odkaz)
Odkaz je odkaz na buňku, ve které se má zjistit, zda obsahuje odkaz.
=ISFORMULA(C4) vrátí NEPRAVDA, pokud buňka C4 obsahuje číslo 5.
Testuje, zda jde o logickou hodnotu (PRAVDA nebo NEPRAVDA).
Pokud dojde k chybě, funkce vrátí NEPRAVDA.
ISLOGICAL(Hodnota)
Vrátí PRAVDA, pokud je Hodnota logickou hodnotou (PRAVDA nebo NEPRAVDA), jinak vrátí NEPRAVDA.
=ISLOGICAL(99) vrátí NEPRAVDA, protože 99 je číslo a ne logická hodnota.
=ISLOGICAL(ISNA(D4)) vrátí PRAVDA na cokoliv, co obsahuje buňka D4, protože ISNA() vrací logickou hodnotu.
Vrátí PRAVDA, pokud buňka obsahuje chybovou hodnotu #N/A (hodnota není k dispozici).
Pokud dojde k chybě, funkce vrátí NEPRAVDA.
ISNA(Hodnota)
Hodnota je hodnota nebo výraz určený k testování.
=ISNA(D3) vrátí jako výsledek NEPRAVDA.
Testuje, zda buňky obsahují text nebo čísla. Pokud ano, vrátí NEPRAVDA.
Pokud dojde k chybě, funkce vrátí PRAVDA.
ISNONTEXT(Hodnota)
Hodnota je jakákoli hodnota nebo výraz, kde se má zjistit, jestli je výsledkem textová hodnota.
=ISNONTEXT(D2) vrátí NEPRAVDA, pokud buňka D2 obsahuje text abcdef.
=ISNONTEXT(D9) vrátí PRAVDA, pokud buňka D9 obsahuje číslo 8.
Vrátí PRAVDA, je-li hodnota číslo.
ISNUMBER(Hodnota)
Hodnota je jakýkoli výraz, u kterého se má zjistit, zda jde o číslo.
=ISNUMBER(C3) vrátí PRAVDA, pokud buňka C3 obsahuje číslo 4.
=ISNUMBER(C2) vrátí NEPRAVDA, pokud buňka C2 obsahuje text abcdef.
Vrátí PRAVDA, je-li hodnota celé liché číslo, nebo NEPRAVDA, je-li celé sudé.
ISODD(Hodnota)
Hodnota je hodnota, která bude testována.
Není-li hodnota celé číslo, číslice za desetinnou čárkou budou ignorovány. Znaménko hodnoty bude také ignorováno.
=ISODD(33) vrátí PRAVDA
=ISODD(48) vrátí NEPRAVDA
=ISODD(3.999) vrátí PRAVDA
=ISODD(-3.1) vrátí PRAVDA
Vrátí PRAVDA (1), pokud číslo není beze zbytku dělitelné dvěma.
ISODD_ADD(Číslo)
Číslo je číslo, které bude testováno.
=ISODD_ADD(5) vrací 1.
Testuje, jestli je obsah jedné nebo více buněk odkaz. Vrátí PRAVDA, pokud je argument odkaz, jinak vrátí NEPRAVDA. Pokud je funkci předán odkaz, funkce nezkoumá hodnotu odkazu.
ISREF(Hodnota)
Hodnota je hodnota, u které má být zjištěno, jestli je to odkaz.
=ISREF(C5) vrátí výsledek PRAVDA, protože C5 je platný odkaz.
=ISREF("abcdef") vrátí vždy NEPRAVDA, protože text nikdy nemůže být odkaz.
=ISREF(4) vrátí NEPRAVDA.
=ISREF(INDIRECT("A6")) vrátí PRAVDA, protože INDIRECT je funkce, která vrací odkaz.
=ISREF(ADDRESS(1; 1; 2;"Sheet2")) vrátí NEPRAVDA, protože ADDRESS je funkce, která vrací text, ačkoliv vypadá jako odkaz.
Vrátí PRAVDA, když je obsah buňky text.
Pokud dojde k chybě, funkce vrátí NEPRAVDA.
ISTEXT(Hodnota)
Hodnota je hodnota, která se má otestovat - text, číslo, logická hodnota, nebo chybová hodnota.
=ISTEXT(D9) vrátí PRAVDA, pokud buňka D9 obsahuje text abcdef.
=ISTEXT(C3) vrátí NEPRAVDA, pokud buňka C3 obsahuje číslo 3.
Vrátí číselnou hodnotu daného parametru. Je-li parametr text nebo NEPRAVDA, vrátí 0.
Pokud se vyskytne chyba, funkce vrátí hodnotu chyby.
N(Hodnota)
Hodnota je parametr určený k převodu na číslo. N() vrátí číselnou hodnotu, pokud je to možné. Logické hodnoty PRAVDA a NEPRAVDA vrátí jako čísla 1 a 0. V případě textu vrátí číslo 0.
=N(123) vrátí 123
=N(TRUE()) vrátí 1
=N(FALSE()) vrátí 0
=N("abc") vrátí 0
=N(1/0) vrátí #DIV/0!
Vrátí chybovou hodnotu #N/A.
NA()
=NA() konvertuje obsah buňky na #N/A.
Vrátí typ hodnoty (1 = číslo, 2 = text, 4 = booleovská hodnota, 8 = vzorec, 16 = chybová hodnota, 64 = matice).
TYPE(Hodnota)
Hodnota je specifická hodnota, pro kterou je určen datový typ.
=TYPE(C2) vrací jako výsledek 2.
=TYPE(D9) vrací jako výsledek 1.