Pomoč LibreOffice 24.8
V tej kategoriji so funkcije informacij.
Podatki v tej tabeli so podlaga za nekatere od primerov v opisih funkcij:
| C | D | |
|---|---|---|
| 2 | vrednost x | vrednost y | 
| 3 | -5 | -3 | 
| 4 | -2 | 0 | 
| 5 | -1 | 1 | 
| 6 | 0 | 3 | 
| 7 | 2 | 4 | 
| 8 | 4 | 6 | 
| 9 | 6 | 8 | 
Poišče informacije o naslovu, oblikovanju ali vsebini celice.
CELL("vrsta_info" [; sklic])
Vrsta_info je niz znakov, ki določa vrsto informacij. Niz znakov je vedno v angleščini. Vseeno je, ali uporabljate velike ali male črke.
| Vrsta_info | Pomen | 
|---|---|
| COL | Najde številko stolpca s sklicem. =CELL("COL";D2) vrne 4. | 
| ROW | Najde številko vrstice s sklicem. =CELL("ROW";D2) vrne 2. | 
| SHEET | Najde številko delovnega lista s sklicem. =CELL("Sheet";Sheet3.D2) vrne 3. | 
| ADDRESS | Najde absolutni naslov celice s sklicem. =CELL("ADDRESS";D2) vrne $D$2. =CELL("ADDRESS";Sheet3.D2) vrne $Sheet3.$D$2. =CELL("ADDRESS";'X:\dr\test.ods'#$Sheet1.D2) vrne 'file:///X:/dr/test.ods'#$Sheet1.$D$2. | 
| FILENAME | Vrne ime datoteke in številko delovnega lista celice s sklicem. =CELL("FILENAME";D2) vrne 'file:///X:/dr/own.ods'#$Sheet1, če je formula v trenutnem dokumentu X:\dr\own.ods na delovnem listu Sheet1. =CELL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) vrne 'file:///X:/dr/test.ods'#$Sheet1. | 
| COORD | Vrne celotni naslov celice v zapisu Lotus™. =CELL("COORD"; D2) vrne $A:$D$2. =CELL("COORD"; Sheet3.D2) vrne $C:$D$2. | 
| CONTENTS | Brez oblikovanja vrne vsebino celice s sklicem. | 
| TYPE | Vrne vrsto vsebine celice. b = prazna celica (angl. blank) l = besedilo, rezultat formule v obliki besedila (angl. label) v = vrednost, rezultat formule v obliki števila (angl. value) | 
| WIDTH | Vrne širino stolpca s sklicem. Enota je število ničel (0) v privzeti pisavi in velikosti, ki jih je mogoče spraviti v stolpec. | 
| PREFIX | Vrne poravnavo celice s sklicem. ' = poravnaj levo " = poravnaj desno ^ = na sredini \ = ponavljanje (trenutno nedejavno) | 
| PROTECT | Vrne stanje zaščite celice za celico. 1 = celica je zaščitena 0 = celica ni zaščitena | 
| FORMAT | Vrne niz znakov, ki nakaže obliko števil. . = število z ločevanjem tisočic F = število brez ločevanja tisočic C = valutna oblika S = eksponentna predstavitev, npr. 1,234+E56 P = odstotki Pri zgornjih oblikah je število decimalnih mest za decimalno vejico navedeno s številko. Primer: oblika #,##0,0 vrne ,1 in oblika 00,000% vrne P3 D1 = MMM-D-LL, MM-D-LL in podobne oblike D2 = DD-MM D3 = MM-LL D4 = DD-MM-LLLL UU:MM:SS D5 = MM-DD D6 = UU:MM:SS AM/PM D7 = UU:MM AM/PM D8 = UU:MM:SS D9 = UU:MM G = Vse druge oblike - (minus) na koncu = negativna števila so označena z barvo () (oklepaji) na koncu = v oblikovni kodi je odprt oklepaj | 
| COLOR | Vrne 1, če so bile negativne vrednosti oblikovane z barvo, sicer pa vrne 0. | 
| PARENTHESES | Vrne 1, če oblikovna koda vsebuje odprt oklepaj (, sicer pa vrne 0. | 
Sklic (seznam možnosti) je preverjani položaj celice. Če je sklic obseg, se celica premakne zgoraj levo od obsega. Če sklica ni, uporabi LibreOffice Calc položaj tiste celice, v kateri je formula. Microsoft Excel uporabi sklic celice, v kateri je kazalka.
Ta funkcija vrne dosedanji rezultat ocene formule, katere del je (z drugimi besedami: rezultat, do kakršnega je pripeljalo dosedanje ocenjevanje). Njena glavna uporaba je skupaj s funkcijo STYLE() pri uporabi izbranih slogov na celicah glede na njihovo vsebino.
CURRENT()
=1+2+CURRENT()
Ta primer vrne 6. Formula je izračunana z leve na desno na naslednji način: 1 + 2 je enako 3, kar preda rezultat datumu, ko naleti na CURRENT(); CURRENT() tako vrne 3, kar se prišteje izvirni 3, da dobimo 6.
=A2+B2+STYLE(IF(CURRENT()>10;"Rdeče”;”Privzeto”))
Primer vrne A2 + B2 (STYLE vrne v tem primeru 0). Če je vsota večja od 10, je slog Rdeče dodeljen celici. Oglejte si funkcijo STYLE za podrobnejšo razlago.
="ču"&CURRENT()
Ta primer vrne čuču.
ORG.OPENOFFICE.CURRENT
Prikaže formulo celice s formulo kot besedilo.
FORMULA(sklic)
sklic je sklic na celico, ki vsebuje formulo.
Neveljaven sklic ali sklic na celico, ki ne vsebuje formule, vrne napako #N/A (ni na voljo).
Če celica A8 vsebuje formulo =SUM(1;2;3), potem
=FORMULA(A8) vrne besedilo =SUM(1;2;3).
Vrne vrednost, če celica ne vsebuje vrednosti napake, ali nadomestno vrednost, če jo.
IFERROR(vrednost; nadomestna_vrednost)
Vrednost je vrednost ali izraz, ki bo vrnjen, če ni enak napaki ali če je ne povzroči.
Nadomestna_vrednost je vrednost ali izraz, ki bo vrnjen, če izraz ali vrednost Vrednost ni enaka napaki ali je ne povzroči.
=IFERROR(C8;C9), kjer celica C8 vsebuje =1/0, vrne vrednost celice C9, ker je 1/0 neveljaven izraz.
=IFERROR(C8;C9), kjer celica C8 vsebuje =1/0, vrne 13, vrednost celice C8, ki ni neveljaven izraz.
Vrne vrednost, če celica ne vsebuje napake #N/A (vrednost ni na voljo), ali nadomestno vrednost, če jo.
IFNA(vrednost; nadomestna_vrednost)
Vrednost je vrednost ali izraz, ki bo vrnjen, če ni enak napaki #N/A ali je ne povzroči.
Nadomestna_vrednost je vrednost ali izraz, ki bo vrnjen, če izraz ali vrednost Vrednost ni enaka napaki #N/A ali je ne povzroči.
=IFNA(D3;D4) vrne vrednost D3, če D3 ne da rezultata #N/A, oz. D4, če ga povzroči.
Vrne specifične informacije o trenutnem delovnem okolju. Funkcija sprejme en besedilni argument in vrne podatke v odvisnosti od tega parametra.
INFO("vrsta")
V naslednji tabeli je seznam vrednosti besedilnega parametra vrsta in vrnjenih vrednosti funkcije INFO.
| Vrednost za »vrsto« | Vrnjena vrednost | 
|---|---|
| "osversion" | Vedno »Windows (32-bit) NT 5.01«, zaradi združljivosti | 
| "system" | Vrsta operacijskega sistema:  | 
| "release" | Identifikator izdaje izdelka; primer: »300m25(Build:9876)« | 
| "numfile" | Zaradi združljivosti vedno 1 | 
| "recalc" | Trenutni način preračunavanja formul, lahko »Samodejno« ali »Ročno« (lokalizirano v jezik LibreOffice) | 
Drugi programi za delo s preglednicami morda sprejmejo lokalizirane vrednosti parametra vrsta, LibreOffice Calc pa sprejme samo angleške vrednosti.
=INFO("release") vrne številko različice LibreOffice, ki jo uporabljate.
=INFO(D5), pri čemer vsebina celice D5 vsebuje niz system, ki vrne vrsto operacijskega sistema.
Vrne TRUE, če je sklic na celico prazen. Ta funkcija se uporablja za preverjanje, ali je vsebina celice prazna. Celica s formulo ni prazna.
ISBLANK(vrednost)
Vrednost je vsebina, ki jo preverjamo.
=ISBLANK(D2) kot rezultat vrne FALSE.
Preveri za napačne pogoje, razen #N/A (ni na voljo) in vrne TRUE ali FALSE.
ISERR(vrednost)
Vrednost je poljubna vrednost ali izraz, za katerega bo preverjeno, če je prisotna vrednost napake, različna od #N/A (ni na voljo).
=ISERR(C8), kjer celica C8 vsebuje =1/0, vrne TRUE, ker je 1/0 napaka.
=ISERR(C9), kjer celica C9 vsebuje =NA(), ker ISERR() ne upošteva napake #N/A (ni na voljo).
Preveri veljavnost pogojev, vključno z vrednostjo napake #N/A (ni na voljo), in vrne TRUE ali FALSE.
ISERROR(vrednost)
Vrednost je ali se sklicuje na vrednost za preverjanje. ISERROR() vrne TRUE, če je napaka, in FALSE, če napake ni.
=ISERROR(C8), kjer celica C8 vsebuje =1/0, vrne TRUE, ker je 1/0 neveljaven izraz.
=ISERROR(C9), kjer celica C9 vsebuje =NA(), vrne TRUE.
Vrne TRUE, če je vrednost sodo celo število ali FALSE, če je vrednost liha.
ISEVEN(vrednost)
Vrednost je vrednost, ki jo želimo preveriti.
Če Vrednost ni celo število, so vse decimalke prezrte. Prezrt je tudi predznak Vrednosti.
=ISEVEN(48) vrne TRUE
=ISEVEN(33) vrne FALSE.
=ISEVEN(0) vrne TRUE
=ISEVEN(-2,1) vrne TRUE
=ISEVEN(3,999) vrne FALSE
Preveri sodost števila. Vrne 1, če je rezultat deljenja števila z 2 celo število.
ISEVEN_ADD(število)
Število je vrednost, ki bo preizkušena.
=ISEVEN_ADD(5) vrne 0.
=ISEVEN_ADD(A1) vrne 1, če celica A1 vsebuje število 2.
Vrne TRUE, če celica vsebuje formulo.
ISFORMULA(sklic)
Sklic pomeni sklic na celico, za katero želimo preveriti, če vsebuje formulo.
=ISFORMULA(C4) vrne FALSE, če celica C4 vsebuje število 5.
Preveri logično vrednost (TRUE ali FALSE).
Če pride do napake, funkcija vrne FALSE.
ISLOGICAL(vrednost)
Vrne TRUE, če je Vrednost logična vrednost (TRUE ali FALSE), v nasprotnem primeru vrne FALSE.
=ISLOGICAL(99) vrne FALSE, ker je 99 število in ne logična vrednost.
=ISLOGICAL(ISNA(D4)) vrne TRUE, ne glede na to, kaj vsebuje celica D4, ker ISNA() vrne logično vrednost.
Vrne TRUE, če celica vsebuje napačno vrednost #N/A (vrednost ni na voljo).
Če pride do napake, funkcija vrne FALSE.
ISNA(vrednost)
Vrednost je vrednost ali izraz, ki ga preverjamo.
=ISNA(D3) kot rezultat vrne FALSE.
Preveri, ali celica vsebuje besedilo ali številke, in vrne FALSE, če je vsebina besedilo.
Če pride do napake, funkcija vrne TRUE.
ISNONTEXT(vrednost)
Vrednost je poljubna vrednost ali poljubni izraz, ki ga preverjamo, bodisi da je besedilo, številke ali Boolova vrednost.
=ISNONTEXT(D2) vrne FALSE, če celica D2 vsebuje besedilo abcdef.
=ISNONTEXT(D9) vrne TRUE, če celica D9 vsebuje število 8.
Vrne TRUE, če se vrednost sklicuje na število.
ISNUMBER(vrednost)
Vrednost je kateri koli izraz, ki ga preverjamo, ali je število ali besedilo.
=ISNUMBER(C3) vrne TRUE, če celica C3 vsebuje število 4.
=ISNUMBER(C2) vrne FALSE, če celica C2 vsebuje besedilo abcdef.
Vrne TRUE, če je vrednost liha, ali FALSE, če je število sodo.
ISODD(vrednost)
Vrednost je vrednost, ki jo želimo preveriti.
Če Vrednost ni celo število, so vse decimalke prezrte. Prezrt je tudi predznak Vrednosti.
=ISODD(33) vrne TRUE
=ISODD(48) vrne FALSE.
=ISODD(3,999) vrne TRUE
=ISODD(-3,1) vrne TRUE
Vrne TRUE (1), če rezultat pri deljenju z 2 ni celo število.
ISODD_ADD(število)
Število je vrednost, ki bo preizkušena.
=ISODD_ADD(5) vrne 1.
Preveri, če je argument sklic. Vrne TRUE, če je argument sklic, sicer vrne FALSE. Če je podan sklic, funkcija ne preuči sklicane vrednosti.
ISREF(vrednost)
Vrednost je vrednost, za katero želite preveriti, ali je sklic.
=ISREF(C5) vrne rezultat TRUE, ker je C5 veljaven sklic.
=ISREF("abcdef") vedno vrne FALSE, saj navadno besedilo nikoli ne more biti sklic.
=ISREF(4) vrne FALSE.
=ISREF(INDIRECT("A6")) vrne TRUE, saj je INDIRECT funkcija, ki vrne sklic.
=ISREF(ADDRESS(1; 1; 2;"DelovniList2")) vrne FALSE, ker je ADDRESS funkcija, ki vrne besedilo, čeprav je videti kot sklic.
Vrne TRUE, če je vsebina celice sklic na besedilo.
Če pride do napake, funkcija vrne FALSE.
ISTEXT(vrednost)
Vrednost je vrednost, število, Boolova vrednost ali napačna vrednost, ki jo preverjamo.
=ISTEXT(D9) vrne TRUE, če celica D9 vsebuje besedilo abcdef.
=ISTEXT(C3) vrne FALSE, če celica C3 vsebuje število 3.
Vrne številsko vrednost danega parametra. Vrne 0, če je parameter besedilo ali FALSE.
Če pride do napake, funkcija vrne vrednost napake.
N(vrednost)
Vrednost je parameter za pretvorbo v številko. N() vrne številsko vrednost, če je to mogoče. Logični vrednosti TRUE in FALSE vrne kot 1 in 0. Besedilo vrne kot 0.
=N(123) vrne 123
=N(TRUE()) vrne 1
=N(FALSE()) vrne 0
=N("abc") vrne 0
=N(1/0) vrne #DIV/0!
Vrne napačno vrednost #N/A.
NA()
=NA() pretvori vsebino celice v #N/A.
Vrne vrsto vrednosti, kjer je 1 = število, 2 = besedilo, 4 = logična vrednost, 8 = formula, 16 = vrednost napake, 64 = matrika.
TYPE(vrednost)
Vrednost je dana vrednost, za katero je potrebno ugotoviti vrsto podatka.
=TYPE(C2) vrne kot rezultat 2.
=TYPE(D9) vrne kot rezultat 1.